Topics on this Page

What is the Windows 2000 Command Processor? How do I get help on commands? How do I create a file name or folder name using the current date (YYYYMMDD)? What environment variables are available to CMD.EXE? What switches are available for running Regedit.exe at a CMD prompt or in a batch file? How can I delete a Key or Value Name using a filename.reg file? What other tools are available for using the registry in batch? What commands can I use in a logon script? How can I perform a procedure on all files in a folder? How do I parse a file name parameter into its’ constituent parts? How do I perform calculations? How do I test / manipulate strings? How do I read a file and process the lines of text? How do I launch a process at a different priority? How do I display the current directory in the Title bar of a batch files command Windows? How can a batch file alter the size of its’ CMD Window? How can I get a batch file to prompt for user input? How can I get a batch file to ‘sleep’ for n seconds? How can I get a batch file to beep for attention? How do I pipe batch output, including commands and responses, to a log file? What is delayed environment variable expansion? What are the conditional processing symbols? How do I send a pop-up message? How do I execute a command in every sub-folder? How do I remove all files and sub-directories from a folder, without removing the folder? How can I send e-mail from a batch script? How can I retrieve basic user data? How can I count the number of lines in a file, and/or display the last n lines? How can I create a file containing all the user names in my domain? ‘<Command>’ is not recognized as an internal or external command, operable program or batch file?

What is the Windows 2000 Command Processor?

Answer: Windows 2000 supports two (2) command processors:

– COMMAND.COM is the command processor for the virtual DOS Machine (VDM), used for processing MS-DOS based applications and scripts.

– CMD.EXE is the native 32-bit command processor, used to open a command prompt and to press batch (.bat) files.

This FAQ addresses CMD.EXE. If you need help troubleshooting 16-bit applications, see Microsoft Knowledge Base articles:

Troubleshooting NTVDM and WOW Startup Errors (Q196453).

Troubleshooting MS-DOS-Based Programs in Windows (Q165214)

Troubleshooting 16-Bit Windows Applications (Q103656).

To identify whether any program is 16-bit or 32-bit:

1. Use Windows Explorer to navigate to the folder that contains the executable (.exe) file.
2. Right-click the .exe file and press Properties.
3. The program is probably 16-bit if there is no Version tab. To be sure, create a shortcut from the .exe file. If the shortcut Properties has a Run in separate memory space check box, it is 16-bit.

To identify whether a running program is 16-bit or 32-bit:

1. Right-click a blank area of the taskbar and press Task Manager.
2. Select the Processes tab.
3. Locate the program in the Image Name column.
4. 16-bit programs run under the virtual DOS Machine (VDM). The program is indented under Ntvdm.exe. Additionally, a 16-bit Windows program has wowexec.exe indented with it. This is the Windows On Windows (WOW) emulator.

How do I get help on commands?

Answer: To get help on commands, open a CMD.EXE prompt and type any of the following:

help – To get a list of supported commands.

<Command Name> /? – to get help on <Command Name>. Example: net /?

<Command Name> <Sub Command Name> /? – to get help on the <Command Name> <Sub Command Name>. Example: net user /?

Some commands provide detail help, such as DIR, SET, FOR, IF, etc., while others only provide minimal information, such as NET USER. To get additional help, create a shortcut to a ntcmds.bat file that contains:

@echo off
start hh.exe ms-its:%WINDIR%\Help\windows.chm::/ntcmds.htm
exit

and set it to run Minimized.

How do I create a file name or folder name using the current date (YYYYMMDD)?

Answer. To parse the date into its’ YYYY, MM, and DD components, we would use the FOR command. When you type Date /T, a typical North American installation would display Day MM/DD/YYYY, like Mon 07/15/2002.

To parse this into the YYYY, MM, and DD components, type:

for /f "Tokens=2-4 Delims=/ " %a in (‘date /t’) do set mm=%a&set dd=%b&set yy=%c

Note When using the FOR command in a batch file, replace % with %%.

To create a folder named 20020715, type MD %yy%%mm%%dd%.

To create a universal date parser, that works on all Windows NT-based systems (Windows NT 4.0, Windows NT 5.0 (Windows 2000), and Windows NT 5.1 (Windows XP, which doesn’t display the Day when using date /t), regardless of date format, we can make use of the fact that when you type Date, a display similar to:

The current date is: Mon 07/15/2002
Enter the new date: (mm-dd-yy)

exhibits the format (mm-dd-yy). Create a batch file, named univdate.bat, in your path, which contains:

@echo off
set $tok=1-3
for /f "tokens=1 delims=.:/-, " %%u in ('date /t') do set $d1=%%u
if "%$d1:~0,1%" GTR "9" set $tok=2-4
for /f "tokens=%$tok% delims=.:/-, " %%u in ('date /t') do (
for /f "skip=1 tokens=2-4 delims=/-,()." %%x in ('echo.^|date') do (
set %%x=%%u
set %%y=%%v
set %%z=%%w
set $d1=
set $tok=))
 

When you type call univdate, the appropriate environment variables are set. In North America, this would typically be mm, dd, and yy.

What environment variables are available to CMD.EXE?

Answer: In addition to the environment variables that are defined using Control Panel / System / Advanced / Environment Variables, Windows 2000 has some built-in variables. To see the environment variables that are available, type SET.

Note The built-in variables are different if you log on locally versus log on to a domain. Notice that %LOGONSERVER% contains the validating domain controller.

Windows 2000 also defines some hidden environment variables that you can use:

What switches are available for running Regedit.exe at a CMD prompt or in a batch file?

Answer: The Windows NT-based Registry Editor, Regedt32.exe, does NOT support batch or command prompt operations. You can use Regedit.exe, with appropriate switches, to silently Merge a filename.reg file with your registry, or to export a registry file.

To silently Merge a filename.reg file, use the following syntax:

regedit /s <Drive:>\FolderName\FileName.reg

To export a filename.reg file, in Windows NT 5.x format, use:

regedit /e "<Drive:>\FolderName\FileName.reg" "KeyPath"

Note The quote marks are only required if the ‘path’ contains spaces.

To export a filename.reg file, in W9x/NT4 format, suitable for merging with W9x/NT4/NT5 registries, use:

regedit /a "<Drive:>\FolderName\FileName.reg" "KeyPath"

How can I delete a Key or Value Name using a filename.reg file?

Answer: To delete a key, using a filename.reg file, use the following syntax:

REGEDIT4

[-keyPath]

Example: To delete the HKEY_LOCAL_MACHINE \Software \McAfee Key, including all sub-keys, and all Value Names, use the following filename.reg file:

REGEDIT4

[-HKEY_LOCAL_MACHINE \Software \McAfee]

Then run:

regedit /s <Drive:>\Folder\FileName.reg

To delete a Value Name, using a filename.reg file, use the following syntax:

REGEDIT4

[keyPath]
"ValueName"=-

Example: To delete the Tweak UI Value Name from the HKEY_LOCAL_MACHINE \SOFTWARE \Microsoft \Windows \CurrentVersion \Run key, use the following filename.reg file:

REGEDIT4

[HKEY_LOCAL_MACHINE \SOFTWARE \Microsoft \Windows \CurrentVersion \Run]
"Tweak UI"=-

What other tools are available for using the registry in batch?

Answer: If you install the Support Tools from the Windows 2000 CD-ROM, you can use REG.EXE to Add, Delete, Copy, Compare, Export, Import, Load a Hive, Query, Save, Restore, and Unload a Hive. To install the Support Tools:

1. Insert the Windows 2000 CD-ROM into your CD-ROM drive.
2. Click Browse this CD, and then open the Support\Tools folder.
3. Double-click Setup.exe, and follow the on-screen instructions.

Using REG.EXE, and Netdom.exe from the Support Tools, you can script a report of all the Windows NT-based workstations in your domain, listing the computer name, O/S version, and service pack, and piping the report to C:\report.txt:

@echo off
setlocal
if exist c:\report.txt del /q c:\report.txt
For /f "Skip=1 Tokens=1" %%a in ('netdom query /domain WORKSTATION') do call :computer "%%a"
endlocal
goto :EOF
:computer
set machine=%1
set machine=%machine:"=%
set cv=
set CSD=
if "%machine%" EQU "The" goto :EOF
if "%machine%" EQU "Directory" goto :EOF
for /f "Skip=3 Tokens=2*" %%i in ('reg QUERY "\\%machine%\HKEY_LOCAL_MACHINE \SOFTWARE \Microsoft \Windows NT\CurrentVersion" /v CurrentVersion') do set cv=%%j
if not defined cv goto :EOF
if "%cv%" LSS "4.0" goto :EOF
for /f "Skip=3 Tokens=2*" %%i in ('reg QUERY "\\%machine%\HKEY_LOCAL_MACHINE \SOFTWARE \Microsoft \Windows NT\CurrentVersion" /v CSDVersion') do set csd=%%j
@echo %machine% %cv% %csd%>>c:\report.txt


What commands can I use in a logon script?

Answer: A logon script can use any command supported by the client O/S.

If you have a mixture of Windows NT-based clients and other Windows clients, you can test if the client platform is Windows NT-based by including the following statement:

if "%OS%"=="Windows_NT" goto winnt

If you need to test for a specific operation system, the following commands should work on all Microsoft operating systems:

ver | find "Windows XP" >nul
if not errorlevel 1 goto WXP
ver | find "Windows 2000" >nul
if not errorlevel 1 goto W2000
ver | find "Windows NT" >nul
if not errorlevel 1 goto WNT
ver | find "Windows 98" >nul
if not errorlevel 1 goto W98
ver | find "Windows 95" >nul
if not errorlevel 1 goto W95
ver | find "Windows ME" >nul
if not errorlevel 1 goto WME
ver | find "OEM Service Release" >nul
if not errorlevel 1 goto WOEM
ver | find "MS-DOS" >nul
if not errorlevel 1 goto DOS
::Unknown
echo ERROR - What are you running?
goto END
:WXP

:end
 

To define the %USERNAME%, %COMPUTERNAME%, and %LOGONSERVER% environment variables on non-Windows NT-based Windows clients, install putinenv.exe on all non-Windows NT-based Windows clients. You must also install WINSET.EXE, from the Windows CD-ROM, on these clients. You can then use the following code in your logon script:

if "%OS%"=="Windows_NT" goto winnt
%windir%\putinenv.exe L
%LogonServer%\NetLogon\Winset USERNAME=%USERNAME%
%LogonServer%\NetLogon\Winset COMPUTERNAME=%COMPUTERNAME%
%LogonServer%\NetLogon\Winset LOGONSERVER=%LOGONSERVER%
:winnt
 

The most used command in a logon script is net use, used for mapping a drive letter to a share. The syntax is:

net use <:Drive:> \\ServerName\ShareName[\folder] /persistent:NO

Note See the NET USE help in the ntcmds.chm file for other options. Windows 2000 can map below a share, but downlevel clients cannot. If you have configured the users home directory, you can use the net use <:Drive:> /home /persistent:NO syntax.

How can I perform a procedure on all files in a folder?

Answer: The FOR command will allow us to process multiple lines of command output. We can use the FOR command to pass the results of a DIR to a process.

If we wanted to rename all .txt files in a folder, whose 2nd-4th character of the file name was upper case ABC, to a .log file, we could use the following example.bat file, and pass the folder name as a parameter (example.bat "C:\Documents and Settings\Jerry\My Documents")

@echo off
setlocal
if {%1}=={} goto syntax
if not exist %1 goto syntax
set folder=%1
::Set folder as current directory
pushd %1
::Strip quote marks
set folder=%folder:"=%
for /f "Tokens=*" %%a in ('dir /b /a-d "%folder%\*.txt"') do call :isabc "%%a"
::Return to previous current directory
popd
endlocal
goto :EOF
:syntax
@echo Syntax: Example FolderPath
endlocal
goto :EOF
:isabc
set filename=%1
::Strip quote marks
set filename=%filename:"=%
::Test 2nd position, for a 3 byte string
if not "%filename:~1,3%" EQU "ABC" goto :EOF
rename %1 *.log


How do I parse a file name parameter into its’ constituent parts?

Answer: When you invoke a batch file with a parameter (%1), you are able to parse it to extract meaningful information.

Note Command Extensions ( /E:ON ), enabled by default, must be on.

You can use these modifiers in combination:

To determine where a batch file was run from, use %~dp0

I have scripted demo.bat to display the various parsing of a file/folder name parameter. Demo.bat contains:

@echo off
@echo Batch file: %~dp0
If {%1}=={} @echo No parameter specified&goto :EOF
:loop
If {%1}=={} goto :EOF
@echo.
@echo ^%%1=%1
@echo ^%%~f1=%~f1
@echo ^%%~d1=%~d1
@echo ^%%~p1=%~p1
@echo ^%%~n1=%~n1
@echo ^%%~x1=%~x1
@echo ^%%~s1=%~s1
@echo ^%%~dp1=%~dp1
@echo ^%%~nx1=%~nx1
::Shift parameter string
shift
goto :loop
 

If I type:

demo "C:\Documents and Settings\Jerry\My Documents\My Pictures\Jerold.jpg"
%SystemRoot%\Notepad.exe "%userprofile%"
 

demo.bat will display:

Batch file: C:\Util\

%1="C:\Documents and Settings\Jerry"
%~f1=C:\Documents and Settings\Jerry
%~d1=C:
%~p1=\Documents and Settings\
%~n1=Jerry
%~x1=
%~s1=C:\DOCUME~1\Jerry
%~dp1=C:\Documents and Settings\
%~nx1=Jerry


How do I perform calculations?

Answer: The SET command can perform calculations. When you type SET /?, part of the help display contains:

"The /A switch specifies that the string to the right of the equal sign is a numerical expression that is evaluated. The expression evaluator is pretty simple and supports the following operations, in decreasing order of precedence:

() - grouping
* / % - arithmetic operators
+ - - arithmetic operators
<< >> - logical shift
& - bitwise and
^ - bitwise exclusive or
| - bitwise or
= *= /= %= += -= - assignment
&= ^= |= <<= >>=
, - expression separator
 

If you use any of the logical or modulus operators, you will need to enclose the expression string in quotes. Any non-numeric strings in the expression are treated as environment variable names whose values are converted to numbers before using them. If an environment variable name is specified but is not defined in the current environment, then a value of zero is used. This allows you to do arithmetic with environment variable values without having to type all those % signs to get their values. If SET /A is executed from the command line outside of a command script, then it displays the final value of the expression. The assignment operator requires an environment variable name to the left of the assignment operator. Numeric values are decimal numbers, unless prefixed by 0x for hexadecimal numbers, and 0 for octal numbers. So 0x12 is the same as 18 is the same as 022. Please note that the octal notation can be confusing: 08 and 09 are not valid numbers because 8 and 9 are not valid octal digits."

We can script Yesterday.bat to calculate yesterdays date, returning the PDMM, PDDD, and PDYY environment variables:

@echo off
call univdate
::Force non-leading zero, as it may cause failure
set /a PDDD=1%DD% - 101
set /a PDMM=1%MM% - 100
set /a PDYY=%YY%
if %PDDD% GTR 0 goto return
set /a PDMM=%PDMM% - 1
if %PDMM% GTR 0 goto isleap
set /a PDDD=31
set /a PDMM=12
set /a PDYY=%PDYY% - 1
goto return
:isleap
if not %PDMM% EQU 2 goto days%PDMM%
::Temporarily use PDDD as a work field
set /a PDDD=%PDYY% / 4
set /a PDDD=%PDDD% * 4
if %PDDD% EQU %PDYY% goto leap
set /a PDDD=28
goto return
:leap
set /a PDDD=29
goto return
:days1
:days3
:days5
:days7
:days8
:days10
set /a PDDD=31
goto return
:days4
:days6
:days9
:days11
set /a PDDD=30
:return
::Force leading zero when day or month is single digit
set /a PDDD=%PDDD% + 100
set PDDD=%PDDD:~1,2%
set /a PDMM=%PDMM% + 100
set PDMM=%PDMM:~1,2%
 

Note To calculate that the year was divisible by 4, a leap year, I could have replaced:

set /a PDDD=%PDYY% / 4
set /a PDDD=%PDDD% * 4
if %PDDD% EQU %PDYY% goto leap

with:

set /a PDDD= %PDYY% ^%% 4
if %PDDD% EQU 0 goto leap

How do I test / manipulate strings?

Answer: If your batch script needs to determine if a string is a sub-set of a larger string, the easiest method is to use environment variable string substitution:

set work=%string:substring=%
if not "%work%" EQU "%string%" @echo %string% contains substring.

If the substring is an environment variable, set work=%string:%substring%=% or set work=%%string:%substring%=%% does NOT work.

You can use the FOR command to parse this expression, but using the CALL command is much easier:

call set work=%%string:%substring%=%%
if not "%work%" EQU "%string%" @echo %string% contains %substring%.

To determine if your path contains a specific folder, call chkpath "folder"

Example: call chkpath "c:\program files\support tools", where chkpath.bat contains:

@echo off
setlocal
set $chkpath=N
if {%1}=={} goto syntax
set fold=%1
:: Strip quotes
set folder=%fold:"=%
call set work=%%path:%folder%=%%
if "%work%" EQU "%path%" goto :end
set $chkpath=Y
goto :end
:syntax
@echo Syntax: ChkPath Folder
:end
endlocal&set $chkpath=%$chkpath%
 

Note chkpath.bat sets the $chkpath environment variable to Y if the string is found.

If you need to determine the position and length of the "folder" string in the path, chkpath.bat should contain:

@echo off
setlocal
set /a $pos=0
set /a $len=0
set $chkpath=N
if {%1}=={} goto syntax
set fold=%1
:: Strip quotes
set folder=%fold:"=%
call set work=%%path:%folder%=%%
if "%work%" EQU "%path%" goto :end
set $chkpath=Y
set find=%folder%###
:lenloop
call set work=%%find:~%$len%,^3%%
if "%work%" EQU "###" goto fndpos
set /a $len=%$len% + 1
goto lenloop
:fndpos
call set work=%%path:~%$pos%^,%$len%%%
if /i "%work%" EQU "%folder%" goto :end
set /a $pos=%$pos% + 1
goto fndpos
:syntax
@echo Syntax: ChkPath Folder
:end
endlocal&set $chkpath=%$chkpath%&set /a $pos=%$pos%&set /a $len=%$len%
 

Note $pos starts at position 0.

Sample Usage

set look=c:\program files\support tools
call chkpath "%look%"
if "%$chkpath%" EQU "Y" @echo %look% is at position %$pos% for a length of %$len%

How do I read a file and process the lines of text?

Answer: To process the contents of a text file, you can parse it with the FOR command:

for /f "Tokens=*" %%a in (filenName.Extension) do set line=%%a&call :parse

for /f "Tokens=*" %%a in (‘type "filenName.Extension"’) do set line=%%a&call :parse

Note See FOR /? for additional options.

Example: To display only those keys that have dword values, and their dword values, in a c:\folder\registry.reg file:

@echo off
setlocal
set key=
for /f "Tokens=*" %%a in ('type d:\zipnew\zz.reg') do set line=%%a&call :parse
endlocal
goto :EOF
:parse
::Strip command control codes
set work=%line:"=%
set work=%work::=%
set work=%work:(=%
set work=%work:)=%
set work=%work:^&=%
set work=%work:^|=%
set work=%work:^>=%
set work=%work:^<=%
set work=%work:^%=%
set work=%work:^!=%
set work=%work:^;=%
::Save the key
if {%work:~0,1%}=={[} set key=%line%&goto :EOF
set dw=%work:dword=%
if "%dw%" EQU "%work%" goto :EOF
@echo %key% - %line%


How do I launch a process at a different priority?

Answer: When you type start /?, you receive:

Starts a separate window to run a specified program or command.

When searching for an executable, if there is no match on any extension,
then looks to see if the name matches a directory name. If it does, the
START command launches the Explorer on that path. If done from the
command line, it is the equivalent to doing a CD /D to that path.


How do I display the current directory in the Title bar of a batch files command Windows?

Answer: The start command can set the initial Title in a command Window.

To cause the batch file to display the current directory every time it changes, add the following commands after each current directory change:

for /f "Tokens=*" %%i in ('CD') do set CurDir=%%i
title %CurDir%


How can a batch file alter the size of its’ CMD Window?

Answer: If you want to scroll the CMD window while a batch file is running, you can alter the Windows width (characters) and depth (screen buffer lines) by issuing a mode command in the batch file:

mode con[:] [cols=c] [lines=n]

where:


con[:] indicates the change is to be made to the current command prompt window.

lines=n specifies the number of lines, n, in the screen buffer.
 

Example: mode con: cols=100 lines=999

How can I get a batch file to prompt for user input?

Answer: The SET command support the /P switch:

SET /P variable=[promptString]

"The /P switch allows you to set the value of a variable to a line of input
entered by the user. Displays the specified promptString before reading
the line of input. The promptString can be empty."

Example: To prompt for folders to DIR:

@echo off
setlocal
:loop
::undefine the %folder% environment variable
set folder=
set /p folder=Type the folder path and press Enter. When finished, press Enter.
if {%folder%}=={} goto :end
@echo.
if not exist %folder% @echo %folder% does NOT exist.&goto :loop
dir %folder%
@echo.
goto loop
:end
endlocal


How can I get a batch file to ‘sleep’ for n seconds?

Answer: The Windows 2000 Resource Kits provide sleep.exe to allow a batch file to sleep for n seconds.

You can emulate this behavior by using the PING (Packet InterNet Groper) command:

ping -n seconds+1 127.0.0.1>nul

To sleep for 15 seconds, type:

ping -n 16 127.0.0.1>nul

How can I get a batch file to beep for attention?

Answer: To cause a batch file to beep for attention, you need to send a BEL character.

To create a Bell.bat in your path:

1. At a CMD prompt, switch (CD) to a folder in your path.
2. Type:

   edit bell.bat
@echo<space><CTRL+P><CTRL+G><ENTER>
<ALT+S> (Saves bell.bat)
<ALT+X> (Exits edit)
 

Note <> indicates that you type the key(s) within the <>.

When you need to beep for attention:

call bell

How do I pipe batch output, including commands and responses, to a log file?

Answer: The general syntax for piping batch output, including commands and responses, to a log file is:

Drive:\BatFolder\BatchName.bat>Drive:\LogFolder\LogName.log 2>&1

What is delayed environment variable expansion?

The default behavior of the CMD command processor is to evaluate an environment variable once per statement execution.

To demonstrate this behavior, assume that your c:\test folder has 3 files:

File1.txt
File2.txt
File3.txt

If you run a batch script containing:

@echo off
cd /d c:\test
@echo on
set LIST=
for %%i in (*) do set LIST=%LIST% %%i
echo %LIST%
 

You would see the following:

C:\TEST\>set LIST=
C:\TEST\>for %i in (*) do set LIST= %i
C:\TEST\>set LIST= File1.txt
C:\TEST\>set LIST= File2.txt
C:\TEST\>set LIST= File3.txt
C:\TEST\>echo File3.txt
C:\TEST\> File3.txt

You can see from this example that the LIST variable is expanded just once when the FOR statement is executed. Since LIST was empty, only the last file found is set into the variable.

Windows 2000 supports delayed environment variable expansion. You must enable delayed environment variable expansion for the CMD session by using the CMD /V:ON switch, or by issuing a setlocal ENABLEDELAYEDEXPANSION command.

With delayed environment variable expansion enabled, you can use the ! instead of the %, as follows:

@echo off
cd /d c:\test
@echo on
set LIST=
for %%i in (*) do set LIST=!LIST! %%i
echo %LIST%
 

This yields the following output:

C:\TEST\>set LIST=
C:\TEST\>for %i in (*) do set LIST=!LIST! %i
C:\TEST\>set LIST=!LIST! File1.txt
C:\TEST\>set LIST=!LIST! File2.txt
C:\TEST\>set LIST=!LIST! File3.txt
C:\TEST\>echo File1.txt File2.txt File3.txt
C:\TEST\> File1.txt File2.txt File3.txt

You can have delayed environment variable expansion enabled by default, if you use Regedt32 to navigate to either of the following keys:

HKEY_LOCAL_MACHINE \Software \Microsoft \Command Processor

HKEY_CURRENT_USER \Software \Microsoft \Command Processor
 

On the Edit menu, Add Value name DelayedExpansion, as a REG_DWORD data type. A data value of 1 enables delayed environment variable expansion and a data value of 0 disables it. Invoking the /V:ON or /V:OFF switch on CMD.EXE and/or using the setlocal ENABLEDELAYEDEXPANSION command, overrides the registry setting for the CMD session.

What are the conditional processing symbols?

Answer: From the ntcmds.chm file:

Conditional processing symbols give you control over the execution of commands.
Processing Commands Conditionally You use conditional processing symbols to issue
multiple commands from the same prompt and to act based on the results of a command.
The ampersand (&) separates multiple commands on one command line.
The parentheses groups multiple commands.
The semicolon or comma (; ,) separate command parameters.
The caret (^) cancels a subsequent command symbol's special meaning so you can use a
command symbol as text.
The double ampersand (&&) causes the command following this symbol to run only if the
command preceding the symbol is successful.
The double pipe (||) causes the command following this symbol to run only if the command
preceding the symbol fails.
 

Examples:

dir filename.txt>nul && type filename.txt is equivalent to if exist filename.txt type filename.txt

dir filename.txt>nul || @echo.>filename.txt is equivalent to if not exist filename.txt @echo.>filename.txt

How do I send a pop-up message?

Answer: The syntax of the net send command is:

net send {name | * | /domain[:name] | /users} message

To send a pop-up to all users in your domain, type:

net send /domain This is a message.

Note Windows NT-based client run the Messenger service by default. Other Windows clients must be running Winpopup.exe to receive the message.

net send jennifer hello will send hello to Jennifer, if she is logged on.

net send /users hello will send hello to all users that are connected to your computer.

To send a files contents to logged on members of one or more domain groups, use:

call sendfilegroup filename.txt group1 [group2 group3 … groupn], where sendfilegroup.bat contains:

@echo off
setlocal ENABLEDELAYEDEXPANSION
if {%2}=={} (echo usage: sndflegrp msgfile group-list) & (goto :EOF)
if not exist %1 (echo usage: sndflegrp msgfile group-list) & (goto :EOF)
set msg=
for /f "Tokens=*" %%m in ('type %1') do set msg=!msg! %%m
:LOOP
if {%2}=={} endlocal&goto :EOF
for /f "Skip=8 Tokens=*" %%i in ('net group %2 /domain') do call :msg "%%i"
shift /2
goto :LOOP
:msg
If %1=="The command completed successfully." goto :EOF
set users=%1
set user=%users:~1,20%##
call :sndmsg>nul 2>&1
if "%user%"=="" goto end
set user=%users:~26,20%##
call :sndmsg>nul 2>&1
if "%user%"=="" goto end
set user=%users:~51,20%##
call :sndmsg>nul 2>&1
goto :EOF
:sndmsg
set user=%user: =%
set user=%user: ##=##%
set user=%user:##=%
set user=%user:"=%
if "%user%"=="" goto :EOF
set comp=%user%
set comp=%comp:$=%
if "%comp%"=="%user%" net send "%user%" %msg%


How do I execute a command in every sub-folder?

Answer: The FOR /R command is meant to traverse sub-folders.

The general syntax is:

FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]

Walks the directory tree rooted at [drive:]path, executing the FOR
statement in each directory of the tree. If no directory
specification is specified after /R then the current directory is
assumed. If set is just a single period (.) character then it
will just enumerate the directory tree.

Examples:

To delete every *.log file in all the folders of your profile, type:

for /r "%userprofile%" %i in (*.log) do del /q "%i"

Note If used in a batch file, the %variable% must be %%variable%%.

To list all the sub-folders of your profile, type:

for /r "%userprofile%" %i in (.) do @echo %i

To list every sub-folder of the current directory, type:

for /r %i in (.) do @echo %i

How do I remove all files and sub-directories from a folder, without removing the folder?

Answer: Typing RD /S /Q <Drive:>\FolderName will delete <Drive:>\FolderName, all it’s files, and sub-folders.

If you do NOT wish to remove the target folder, create DELTREE.BAT in your path:

@echo off
pushd %1
del /q *.*
for /f "Tokens=*" %%i in (‘dir /B’) do rd /s /q "%%i"
popd

To delete all the files and sub-directories in <Drive:>\My Test Folder, type:

DELTREE "<Drive:>\My Test Folder"

How can I send e-mail from a batch script?

Answer: If you wish to send an e-mail message from the command line or from a batch file, you can use BLAT freeware.

After installing BLAT by typing:

blat -install mail.jsiinc.com Jerry@jsiinc.com 3, I received:

Failed to open registry key for Blat profile , using default.
SMTP server set to mail.jsiinc.com, on port 25 with user Jerry@jsiinc.com, retry 3 time(s)

When I typed:

blat c:\temp\blatread.txt -to jerry@jsiinc.com -s "This is a BLAT test", the CMD window displayed:

Sending c:\temp\blatread.txt to jerry@jsiinc.com
Subject:This is a BLAT test
Login name is Jerry@jsiinc.com

Try number 1 of 3.
 

AND I received the e-mail, containing the contents of c:\temp\blatread.txt.

5527 [cchev] How can I retrieve basic user data?

Answer: I have scripted GetUserInfo.bat to retrieve basic user data. The syntax is:

call getuserinfo UserName

where UserName must be quoted if it contains any space characters.

To verify that the UserName was found, use a statement like:

if not defined $line1 goto NotFound

After verifying that the UserName was found, you can access the basic user data by using the environment variables from the following table:

GetUserInfo.bat contains:

@echo off
if {%1}=={} goto syntax
set /a cnt=0
::NOTE: If you don't have a domain, change the following statemnt to: for /f "Tokens=*" %%i in ('net user %1') do set line=%%i&call :parse
for /f "Skip=1 Tokens=*" %%i in ('net user %1 /domain') do set line=%%i&call :parse
if %cnt% EQU 0 set $line1=
set cnt=
set line=
goto :EOF
:syntax
endlocal
@echo syntax: Call GetUserInfo "UserName"
goto :EOF
:parse
set /a cnt=%cnt% + 1
if /i "%line%"=="The command completed successfully." goto :EOF
if %cnt% GTR 17 goto :EOF
set $line%cnt%=%line:~29,256%
 

Sample Usage

To implement a user locator for a single domain controller domain, create a Locator$ share on your domain controller granting Domain Users Read and Write permissions, and Creator Owner delete permission. Add the following code to your logon script:


call getuserinfo "%username%"
if defined $line1 del /q "%LOGONSERVER%\Locator$\%userName%.*"
if defined $line1 @echo %$line2%>"%LOGONSERVER%\Locator$\%userName%.%ComputerName%"
 

To locate a user, type:

dir "%LOGONSERVER%\Locator$\UserName.*"

How can I count the number of lines in a file, and/or display the last n lines?

Answer: I have scripted Tail.bat to perform both functions.

The syntax is:

tail FileName [NumberOfLinesToDisplay]

If NumberOfLinesToDisplay is 0, you can set the file line count by using:

for /f %%i in (‘tail FileName 0’) do set lines=%%i

If NumberOfLinesToDisplay is omitted, 10 lines will be displayed.

If NumberOfLinesToDisplay is greater than the lines in the file, all lines in the file will be displayed.

Tail.bat contains:

@echo off
if {%1}=={} @echo FileName parameter requied.&goto :EOF
if not exist %1 @echo %1 does NOT exist.&goto :EOF
setlocal
set file=%1
set /a number=10
if not {%2}=={} set /a number=%2
for /f %%i in ('find /v /c "" ^< %file%') do set /a lines=%%i
@echo %lines% lines in file %file%.
if %number% GEQ %lines% set /a start=0&goto console
set /a start=%lines% - %number%
:console
more /e +%start% %file%
endlocal


How can I create a file containing all the user names in my domain?

Answer: I have scripted AllUsers.bat to retrieve the list of all user names in the client’s domain. The syntax is:

call AllUsers "FileName"

where FileName is the full path to the file that will contain the user names.

AllUsers.bat contains:

@echo off
if {%1}=={} @echo Syntax: AllUsers "FileName"&goto :EOF
setlocal
if exist %1 del /q %1
set filename=%1
for /f "Skip=6 Tokens=*" %%i in ('net user /domain') do set line=%%i&call :parse
endlocal
goto :EOF
:parse
set name=%line:~0,25%
If /i "%name%" EQU "The command completed suc" goto :EOF
call :strip
set name=%line:~25,25%
if not "%name%" EQU "" call :strip
set name=%line:~50,25%
if not "%name%" EQU "" call :strip
goto :EOF
:strip
set short=%name%#
set short=%short: =%
set short=%short: #=#%
set short=%short:#=%
@echo %short%>>%filename%
 

Sample Usage

To create of report of all user names whose password has expired, or will expire today, Expired.bat contains:

@echo off
if {%1}=={} @echo syntax: Expired "ReportFile"&goto :EOF
setlocal
set filename=%1
if exist %filename% del /q %filename%
::Format Today as YYYYMMDD where %date% contains DAY MM/DD/YYYY
set today=%date:~10,4%%date:~4,2%%date:~7,2%
call allusers "%TEMP%\AllUsers.txt"
for /f "Tokens=*" %%i in ('type "%TEMP%\AllUsers.txt"') do set user=%%i&call :report
if exist %filename% del /q %filename%
endlocal
goto :EOF
:report
call GetUserInfo "%user%"
if not defined $line1 goto :EOF
if /i "%$line6%" EQU "No" goto :EOF
if /i "%$line9%" EQU "Never" goto :EOF
::Set Password Expires to YYYYMMDD
set passexp=%$line9:~6,4%%$line9:~0,2%%$line9:~3,2%
If "%passexp%" GTR "%today%" goto :EOF
::Set ruser to 26 characters
set work=%user% #
set ruser=%work:~0,26%
::set Full Name to 40 characters
set work=%$line2% #
set fullname=%work:~0,40%
@echo %ruser%%fullname%%passexp%>>%filename%


‘<Command>’ is not recognized as an internal or external command, operable program or batch file?

Answer: If you receive the subject error message, the most likely cause is that the %SystemRoot%\System32 folder is no longer in your path. Most systems should have a PATH variable that begins with entries similar to:

PATH=C:\WINNT\system32;C:\WINNT;C:\WINNT\system32\WBEM;

Another possible reason for this error is that some application install changed the Path Value Name, in the registry, from a REG_EXPAND_SZ data type to a REG_SZ data type.

If this is your problem:

1. Use Regedt32.exe to navigate to:

   HKEY_LOCAL_MACHINE \System \CurrentControlSet \Control \Session Manager\Environment

2. If the Path Value Name is a type REG_SZ, double-click it and paste the data value into Notepad.
3. Delete the Path Value Name.
4. On the Edit menu, Add Value name Path, as a REG_EXPAND_SZ data type.
5. In the String Editor, paste the data value from Notepad.
6. You may have to restart your computer.